@echo off
title qrcpTool右键菜单添加   by:ilaoyao
%1 start "" mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c ""%~dp0%~n0"" ::","","runas",1)(window.close)&&exit
set qrcppath=%~dp0
 
 
::传输当前文件菜单
reg add HKEY_CLASSES_ROOT\*\shell\qrcp /ve /d QRCP发送 /f>nul 2>nul
reg add HKEY_CLASSES_ROOT\*\shell\qrcp /v icon /d """"%qrcppath%qrcptool.exe"""" /f>nul 2>nul
reg add HKEY_CLASSES_ROOT\*\shell\qrcp\command /ve /d """"%qrcppath%qrcptool.exe""" -s """%%v"""" /f>nul 2>nul
 
::共享当前文件夹目录菜单
reg add HKEY_CLASSES_ROOT\Directory\shell\qrcp /ve /d QRCP发送 /f>nul 2>nul
reg add HKEY_CLASSES_ROOT\Directory\shell\qrcp /v icon /d """"%qrcppath%qrcptool.exe"""" /f>nul 2>nul
reg add HKEY_CLASSES_ROOT\Directory\shell\qrcp\command /ve /d """"%qrcppath%qrcptool.exe""" -s """%%v"""" /f>nul 2>nul
 
::当前位置接收文件菜单
reg add HKEY_CLASSES_ROOT\Directory\background\shell\qrcp /ve /d QRCP接收 /f>nul 2>nul
reg add HKEY_CLASSES_ROOT\Directory\background\shell\qrcp /v icon /d """"%qrcppath%qrcptool.exe"""" /f>nul 2>nul
reg add HKEY_CLASSES_ROOT\Directory\background\shell\qrcp\command /ve /d """"%qrcppath%qrcptool.exe""" -r """%%v"""" /f>nul 2>nul
 
echo.
echo   QrcpTool右键菜单添加完成！
echo _________________________________________________
echo.
echo                  使用方法提示
echo _________________________________________________
echo. 
echo   1） 文件或文件夹上右键菜单点击「QRCP发送」传送该文件。
echo.
echo   2） 空白处右键菜单点击「QRCP接收」接收文件到该目录。
echo.
echo.
echo   ^>^>^> 请按任意键退出. . .
pause>nul